Some/build.gradle.kts at main · MessiasLima/Some · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
plugins {
    alias(libs.plugins.android.library) apply false
    alias(libs.plugins.kotlin.jvm) apply false
    alias(libs.plugins.mavenPublish) apply false
    alias(libs.plugins.detekt) apply false

    alias(libs.plugins.dokka)
    alias(libs.plugins.gitHooks)
}

group = "dev.appoutlet"
version = "0.4.0"

repositories {
    mavenCentral()
}

dependencies {
    dokkaHtmlPlugin(libs.dokka.versioning)
    dokka(projects.android)
    dokka(projects.core)
    dokka(projects.kotest)
}

tasks.named("prepareKotlinBuildScriptModel") {
    dependsOn(":installGitHooks")
}

dokka {
    dokkaPublications.html {
        outputDirectory.set(rootDir.resolve("docs/reference/version/${project.version}"))
        includes.from("$rootDir/docs/reference/index.md")
    }

    pluginsConfiguration {
        html {
            customAssets.from("$rootDir/docs/logo-icon.svg")
            footerMessage.set("© AppOutlet, Lda")
        }

        versioning {
            olderVersionsDir.set(rootDir.resolve("docs/reference/version"))
        }
    }
}

tasks.register("generateDokkaRedirect") {
    description = "Generate a html file that redirects to the latest documentation version"

    val version = project.version
    val targetDir = project.file("docs/reference/latest")

    doLast {
        targetDir.mkdirs() // Creates the dir if it doesn't exist, does nothing if it does

        File(targetDir, "index.html").writeText(
            """<meta http-equiv="refresh" content="0; url=../version/$version/">"""
        )
    }
}

tasks.named("dokkaGenerate") {
    finalizedBy("generateDokkaRedirect")
}